Le Mod Tejon's Gold Weight

bonjour à tous (j'espère qu'il y a encore du monde par ici),

j'essaie de faire tourner le mod Tejon's Gold Weight (il crée un poids pour les pièces d'or), mais ça ne marche pas bien.

sur mon Morrowind (français) ça donne 2 objets "Or" dans l'inventaire: un objet "Or" classique (qui représente les pièces d'or transportées), et un objet "Poids Or" qui indique le poids des pièces transportées. ce n'est donc pas très heureux... (à moins que ce soit prévu comme ça?!)

ceci dit le poids est bien pris en compte; si on fait abstraction de l'objet "Poids Or" et que l'on ne manipule que l'objet Or classique, les calculs de poids semblent bien pris en compte.

je me suis dis que c'est peut-être dû au fait que le mod n'est pas traduit. alors j'ai essayé de le traduire, mais je ne vois pas grand-chose à traduire, et au final ça n'a rien changé (à part l'étiquette "Poids Or" à la place de "Gold Weight".

puis j'ai extrait le script du mod (que je mets en fin de message) mais là non plus je ne vois rien à traduire là-dedans.

donc je me demande si c'est un pb de traduction ou d'autre chose. à moins que le mod soit prévu comme ça (?).

pour la petite histoire je ne m'intéresse qu'à ce mod (pour le poids des pièces) car ça semble le seul qui est réputé tourner sur openmw. et au final c'est openmw qui m'intéresse.

quelqu'un peut m'aider?

salut!

PS:

# tejon_gold_weight_script ====================================================
begin tejon_gold_weight_script

short state
long gold
long weight
long offset

if ( menumode == 1 )
  return
endif
if ( state < 0 ) ; Use negative state as frame delay.
  set state to ( state + 1 )
  return
endif
if ( state > 4 ) ; Safety catch. 4 is the highest valid state.
  set state to -5
  return
endif

if ( state == 0 )
set gold to ( Player -> getItemCount, gold_001 )
set state to 1
return
endif ; End state 0.

if ( state == 1 )
set weight to ( Player -> getItemCount, tejon_gold_weight_item )
set state to 2
return
endif ; End state 1.

if ( state == 2 )
set offset to ( gold - weight )
if ( offset > 0 )
  set state to 3
  return
elseif ( offset < 0 )
  set state to 4
  return
else
  set state to -5
  return
endif
endif ; End state 2.

if ( state == 3 )
while ( offset >= 1024 )
  Player -> addItem, tejon_gold_weight_item, 1024
  set offset to ( offset - 1024 )
endwhile
if ( offset >= 512 )
  Player -> addItem, tejon_gold_weight_item, 512
  set offset to ( offset - 512 )
endif
if ( offset >= 256 )
  Player -> addItem, tejon_gold_weight_item, 256
  set offset to ( offset - 256 )
endif
if ( offset >= 128 )
  Player -> addItem, tejon_gold_weight_item, 128
  set offset to ( offset - 128 )
endif
if ( offset >= 64 )
  Player -> addItem, tejon_gold_weight_item, 64
  set offset to ( offset - 64 )
endif
if ( offset >= 32 )
  Player -> addItem, tejon_gold_weight_item, 32
  set offset to ( offset - 32 )
endif
if ( offset >= 16 )
  Player -> addItem, tejon_gold_weight_item, 16
  set offset to ( offset - 16 )
endif
if ( offset >= 8 )
  Player -> addItem, tejon_gold_weight_item, 8
  set offset to ( offset - 8 )
endif
if ( offset >= 4 )
  Player -> addItem, tejon_gold_weight_item, 4
  set offset to ( offset - 4 )
endif
if ( offset >= 2 )
  Player -> addItem, tejon_gold_weight_item, 2
  set offset to ( offset - 2 )
endif
if ( offset == 1 )
  Player -> addItem, tejon_gold_weight_item, 1
  set offset to 0
endif
set state to -5
return
endif ; End state 3.

if ( state == 4 )
while ( offset <= -1024 )
  Player -> removeItem, tejon_gold_weight_item, 1024
  set offset to ( offset + 1024 )
endwhile
if ( offset <= -512 )
  Player -> removeItem, tejon_gold_weight_item, 512
  set offset to ( offset + 512 )
endif
if ( offset <= -256 )
  Player -> removeItem, tejon_gold_weight_item, 256
  set offset to ( offset + 256 )
endif
if ( offset <= -128 )
  Player -> removeItem, tejon_gold_weight_item, 128
  set offset to ( offset + 128 )
endif
if ( offset <= -64 )
  Player -> removeItem, tejon_gold_weight_item, 64
  set offset to ( offset + 64 )
endif
if ( offset <= -32 )
  Player -> removeItem, tejon_gold_weight_item, 32
  set offset to ( offset + 32 )
endif
if ( offset <= -16 )
  Player -> removeItem, tejon_gold_weight_item, 16
  set offset to ( offset + 16 )
endif
if ( offset <= -8 )
  Player -> removeItem, tejon_gold_weight_item, 8
  set offset to ( offset + 8 )
endif
if ( offset <= -4 )
  Player -> removeItem, tejon_gold_weight_item, 4
  set offset to ( offset + 4 )
endif
if ( offset <= -2 )
  Player -> removeItem, tejon_gold_weight_item, 2
  set offset to ( offset + 2 )
endif
if ( offset == -1 )
  Player -> removeItem, tejon_gold_weight_item, 1
  set offset to 0
endif
set state to -5
return
endif ; End state 4.

end tejon_gold_weight_script