4 réponses à ce sujet

[Ariolas]

Bonjour, je suis en train de me modder une petite maison, et dans la cave je voulais faire un activator me permettant de me TP un peu partout dans morro.

J'ai donc voulu utiliser un derivé du script decrit ICI

Jai remplacé les OnPCEquip par des onactivate, et j'obtient donc ce script

Spoiler

Begin Teleport_autel

short button
short button1
short button2
short messageOn
short reset

if ( MenuMode == 1 )
	Return
endif


if ( OnActivate == 0 )
 set reset to 0
endif

if ( reset == 1 )
 return
endif


if ( OnActivate == 1 )
 if ( reset == 0 )
 	 messagebox "Où voulez-vous aller ?", "Nulle Part", "Ald'Ruhn", "Balmora", "Caldéra", "Coeurébène", "Dagon Fel", "Gnaar Mok", "Gnisis", "Destinations Suivantes"
 	 set messageOn to 1
 endif
endif

if ( messageOn == 1 )

 set button to GetButtonPressed
 
 if ( button >= 0 )
 	 set messageOn to 0
 endif

 ;Nulle Part
 if ( button == 0 )
 	 set reset to 1
 return

 ;Ald'Ruhn
 elseif ( button == 1 )
 	 playsound "conjuration hit"
 	 Player->PositionCell -12415, 56790, 2582 180 "Ald'Ruhn"
 	 set reset to 1

 ;Balmora
 elseif ( button == 2 )
 	 playsound "conjuration hit"
 	 Player->PositionCell -23692, -15541, 508 90 "Balmora"
 	 set reset to 1
 	 return

 ;Caldéra
 elseif ( button == 3 )
 	 playsound "conjuration hit"
 	 Player->PositionCell -11988, 19932, 1401 90 "caldéra"
 	 set reset to 1
 	 return

 ;Coeurébène
 elseif ( button == 4 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 12637, -100652, 1335 270 "coeurébène"
 	 set reset to 1
 	 return

 ;Dagon Fel
 elseif ( button == 5 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 62222, 182560, 159 225 "dagon fel"
 	 set reset to 1
 	 return

 ;Gnaar Mok
 	 elseif ( button == 6 )
 	 playsound "conjuration hit"
 	 Player->PositionCell -60725, 26189, 237 65 "gnaar mok"
 	 set reset to 1
 	 return

 ;Gnisis
 elseif ( button == 7 )
 	 playsound "conjuration hit"
 	 Player->PositionCell -83582, 92484, 1012 270 "gnisis"
 	 set reset to 1
 	 return

 ;Destinations Suivantes
 elseif ( button == 8 )
 	 messagebox "Où voulez-vous aller ?", "Nulle Part", "Hla Oad", "Khuul", "Maar Gan", "Molag Maar", "Mont Ecarlate", "Pélagiad", "Porte des Ames", "Destinations Suivantes"
 	 set messageOn to 2
 	 set reset to 1

 endif
endif

endif

if ( messageOn == 2 )

 set button1 to GetButtonPressed

 if ( button1 >= 0 )
 	 set messageOn to 0
 endif

 ;Nulle Part
 if ( button1 == 0 )
 	 set reset to 1
 	 return

 ;Hla Oad
 elseif ( button1 == 1 )
 	 playsound "conjuration hit"
 	 Player->PositionCell -46368, -38725, 169 260 "Hla Oad"
 	 set reset to 1

 ;Khuul
 elseif ( button1 == 2 )
 	 playsound "conjuration hit"
 	 Player->PositionCell -67819, 140455, 180 270 "khuul"
 	 set reset to 1
 	 return

 ;Maar Gan
 elseif ( button1 == 3 )
 	 playsound "conjuration hit"
 	 Player->PositionCell -19538, 103128, 2314 270 "maar gan"
 	 set reset to 1
 	 return

 ;Molag Mar
 elseif ( button1 == 4 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 110659, -62347, 2052 0 "molag mar"
 	 set reset to 1
 	 return

 ;Mont Ecarlate
 elseif ( button1 == 5 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 25129, 68875, 14410 220 "région du mont ecarlate"
 	 set reset to 1
 	 return

 ;Pélagiad
 elseif ( button1 == 6 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 2860, -56469, 1537 85 "pélagiad"
 	 set reset to 1
 	 return

 ;Porte des Ames
 elseif ( button1 == 7 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 20466, 37577, 942 5 "Porte des ames"
 	 set reset to 1
 	 return

 ;Destinations Suivantes
 elseif ( button1 == 8 )
 	 messagebox "Où voulez-vous aller ?", "Nulle Part", "Sadrith Mora", "Seyda Nihyn", "Suran", "Tel Aruhn", "Tel Branora", "Tel Mora", "Vos", "Vivec"
 	 set messageOn to 3
 	 set reset to 1

 endif
endif

endif

if ( messageOn == 3 )

 set button2 to GetButtonPressed

 if ( button2 >= 0 )
 	 set messageOn to 0
 endif

 ;Nulle Part
 if ( button2 == 0 )
 	 set reset to 1
 	 return

 ;Sadrith Mora
 elseif ( button2 == 1 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 150299, 31719, 652 135 "Sadrith Mora"
 	 set reset to 1

 ;Seyda Nihyn
 elseif ( button2 == 2 )
 	 playsound "conjuration hit"
 	 Player->PositionCell -11136, -70831, 230 190 "seyda nihyn"
 	 set reset to 1
 	 return

 ;Suran
 elseif ( button2 == 3 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 54924, -52728, 882 325 "suran"
 	 set reset to 1
 	 return

 ;Tel Aruhn
 elseif ( button2 == 4 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 125328, 45809, 1470 0 "tel aruhn"
 	 set reset to 1

 ;Tel Branora
 elseif ( button2 == 5 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 124974, -102299, 777 90 "tel branora"
 	 set reset to 1
 	 return

 ;Tel Mora
 elseif ( button2 == 6 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 107025, 117293, 185 30 "tel mora"
 	 set reset to 1
 	 return

 ;Vos
 elseif ( button2 == 7 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 92991, 116762, 1396 90 "vos"
 	 set reset to 1

 ;Vivec
 elseif ( button2 == 8 )
 	 playsound "conjuration hit"
 	 Player->PositionCell 46967, -81879, 772 270 "vivec"
 	 set reset to 1
 	 return
 endif
endif


endif

End

Néanmoins, au moment d'arriver dans le jeu, je tente d'activer l'item ( j'ai pris ici un autel de culte impérial, que j'ai modifier) et rien ne ce passe...

quelqu'un pourrait-il m'aider SVP?

( je precise qu'avec OnPCEquip, j'ai mis le script sur un item, et sa marche impeccable )

EDIT : J'ai refait mon post, et j'ai mis en bleu les endif en trop.

Modifié par Ariolas, 02 juillet 2010 - 13:19.

[Kira]

Bonsoir Ariolas...

OnActivate est une fonction, et n'a donc pas besoin d'être déclaré en début de script... Si tu le déclare, le jeu va le considérer comme une variable, et il ne réagira plus au fait que l'objet a été activé...

Il me semble aussi que tu as laissé dans le premier bloc une instruction "Set OnPCEquip to 0"... Normalement, ça ne devrait pas avoir d'incidence, mais ça sera plus propre et élégant sans...

[Ariolas]

Kira, le 30 juin 2010 - 23:00, dit :

Bonsoir Ariolas...

onactivate est une fonction, et n'a donc pas besoin d'être déclaré en début de script... Si tu le déclare, le jeu va le considérer comme une variable, et il ne réagira plus au fait que l'objet a été activé...

Il me semble aussi que tu as laissé dans le premier bloc une instruction "Set OnPCEquip to 0"... Normalement, ça ne devrait pas avoir d'incidence, mais ça sera plus propre et élégant sans...

effectivement, je viend e voir sa sur le tuto de script, et j'ai immediatement testé cela, esperant regler le soucis...En vain ^^"

mais je n'avais pas vu le setOnPCequip....je teste ça desuite

Merci bien pour tes reponses toujours aussi rapides


EDIT: je viend e tester sans le setOnPCEquip, et.... rien :'(

Modifié par Ariolas, 30 juin 2010 - 23:07.

[elendell]

Bonjour Ariolas,

Je ne comprends pas pourquoi tu as fait un dérivé d'un script qui ne fonctionnait pas au lieu de partir de la correction que j'avais faite 3 messages plus loin.

D'autre part, pour donner envie aux autres modeurs de t'aider, il serait bien que les scripts que tu postes soit lisibles plus facilement. Pour ça, il faut que tu utilises les tabulations et que tu postes ton script correctement mis en page entre des balises "Code" ou "HTML Code" (menu "Autres styles").

Tu verras que si tu utilises les tabulations, tu t'en sortiras toi-même bien mieux avec tes scripts. Il faut aussi quand tu postes un script que tu précises si c'est un script prévu avec ou sans Tribunal.

Autre élément utile : Utilise le débugueur de scripts. Voici ce que donne l'analyse du débugueur sur ton script :

Spoiler

                     DebugTES3 version 2.03 : script "teleport_autel"
                    --------------------------------------------------


Liste des erreurs :
---------------------
    - Ligne 100 : un 'endif' en trop (l'erreur a probablement été faite entre la ligne 31 et la ligne 100).
    - Ligne 171 : un 'endif' en trop (l'erreur a probablement été faite entre la ligne 102 et la ligne 171).
    - Ligne 241 : un 'endif' en trop (l'erreur a probablement été faite entre la ligne 240 et la ligne 241).



Liste des variables locales utilisées :
-----------------------------------------
    - "button" (type SHORT)
    - "button1" (type SHORT)
    - "button2" (type SHORT)
    - "messageon" (type SHORT)
    - "reset" (type SHORT)



Liste des variables globales utilisées :
------------------------------------------
    - "onpcequip" (type indéterminé)



Liste des objets physiques utilisés :
---------------------------------------
    - "player" (type OBJET)



Liste des autres objets utilisés :
------------------------------------
    - "conjuration hit" (type SON)
    - "ald'ruhn" (type CELLULE)
    - "balmora" (type CELLULE)
    - "caldéra" (type CELLULE)
    - "coeurébène" (type CELLULE)
    - "dagon fel" (type CELLULE)
    - "gnaar mok" (type CELLULE)
    - "gnisis" (type CELLULE)
    - "hla oad" (type CELLULE)
    - "khuul" (type CELLULE)
    - "maar gan" (type CELLULE)
    - "molag mar" (type CELLULE)
    - "région du mont ecarlate" (type CELLULE)
    - "pélagiad" (type CELLULE)
    - "porte des ames" (type CELLULE)
    - "sadrith mora" (type CELLULE)
    - "seyda nihyn" (type CELLULE)
    - "suran" (type CELLULE)
    - "tel aruhn" (type CELLULE)
    - "tel branora" (type CELLULE)
    - "tel mora" (type CELLULE)
    - "vos" (type CELLULE)
    - "vivec" (type CELLULE)

Note que les 3 erreurs de "endif" signalées auraient été visibles d'un seul coup d'œil si tu avais utilisé les tabulations.

Essaye de faire un dérivé de mon script et si ça ne marche pas, poste-le ici, correctement mis en page et après passage au débugueur.

[Ariolas]

Merci pour ta réponse, en faite, il n'y a pas de tabulation, car j'ai simplement copier le script ( le mod mis en ligne apr l'auteur n'étant plus dispo).

De plus, ce script fonctionnait, avec OnPCEquip ( je l'utilise régulièrement), mais je souhaitais le créer DANS UN CADRE PERSONNEL un teleporteur universel.

Sinon, demande a Kira, je lui ai envoyer des script fait entierement par moi, et la, y'en a des tab^^ ( 2ans de coddage sa donne certains reflexes^^).

Je l'ai prévu sans tribunal au départ, mais si c'est nécessaire, j'intègrerais tribunal ( je sais que cette extension rajoute et debug certaines fonctions^^)

Je précise également que la casse des fonctions est respectée ( mais mes majuscules ne sont aps passées, je vais essayer d'editer) je vais de ce pas re-éditer mon post


EDIT :

J'ai affecter ce script qui effectivement fonctionne ^^

Spoiler

Begin Teleport

short status
short button
short button1
short button2


if ( MenuMode == 1 )
 	Return
endif

if ( OnActivate == 1 )
 	messagebox "Où voulez-vous aller ?", "Nulle Part", "Ald'Ruhn", "Balmora", "Caldéra", "Coeurébène", "Dagon Fel", "Gnaar Mok", "Gnisis", "Destinations Suivantes"
 	set status to 1
endif

if ( status == 1 )

	set button to GetButtonPressed

 	if ( button >= 1 )
 	if ( button < 8 )
 	playsound "conjuration hit"
 	set status to 0
 	endif
 	endif

 	if ( button == 0 ) ;Nulle Part
 	set status to 0
 	return
 	elseif ( button == 1 ) ; Ald'Ruhn
 	Player->PositionCell -12415, 56790, 2582 180 "Ald'Ruhn"
 	elseif ( button == 2 ) ; Balmora
 	Player->PositionCell -23692, -15541, 508 90 "Balmora"
 	elseif ( button == 3 ) ; Caldéra
 	Player->PositionCell -11988, 19932, 1401 90 "caldéra"
 	elseif ( button == 4 ) ; Coeurébène
 	Player->PositionCell 12637, -100652, 1335 270 "coeurébène"
 	elseif ( button == 5 ) ; Dagon Fel
 	Player->PositionCell 62222, 182560, 159 225 "dagon fel"
 	elseif ( button == 6 ) ; Gnaar Mok
 	Player->PositionCell -60725, 26189, 237 65 "gnaar mok"
 	elseif ( button == 7 ) ; Gnisis
 	Player->PositionCell -83582, 92484, 1012 270 "gnisis"
 	elseif ( button == 8 ) ; Destinations Suivantes
 	set status to 2
	endif

endif

if ( status == 2 )
	messagebox "Où voulez-vous aller ?", "Nulle Part", "Hla Oad", "Khuul", "Maar Gan", "Molag Maar", "Mont Ecarlate", "Pélagiad", "Porte des Ames", "Destinations Suivantes"
	set status to 3
endif

if ( status == 3 )

 	set button1 to GetButtonPressed

 	if ( button1 >= 1 )
 	if ( button1 < 8 )
 	playsound "conjuration hit"
 	set status to 0
 	endif
 	endif

 	if ( button1 == 0 ) ;Nulle Part
 	set status to 0
 	return
 	elseif ( button1 == 1 ) ;Hla Oad
 	Player->PositionCell -46368, -38725, 169 260 "Hla Oad"
 	elseif ( button1 == 2 ) ;Khuul
 	Player->PositionCell -67819, 140455, 180 270 "khuul"
 	elseif ( button1 == 3 ) ;Maar Gan
 	Player->PositionCell -19538, 103128, 2314 270 "maar gan"
 	elseif ( button1 == 4 ) ;Molag Mar
 	Player->PositionCell 110659, -62347, 2052 0 "molag mar"
 	elseif ( button1 == 5 ) ;Mont Ecarlate
 	Player->PositionCell 25129, 68875, 14410 220 "région du mont ecarlate"
 	elseif ( button1 == 6 ) ;Pélagiad
 	Player->PositionCell 2860, -56469, 1537 85 "pélagiad"
 	elseif ( button1 == 7 ) ;Porte des Ames
 	Player->PositionCell 20466, 37577, 942 5 "Porte des ames"
 	elseif ( button1 == 8 ) ;Destinations Suivantes
 	set status to 4
 	endif

endif

if ( status == 4 )
	messagebox "Où voulez-vous aller ?", "Nulle Part", "Sadrith Mora", "Seyda Nihyn", "Suran", "Tel Aruhn", "Tel Branora", "Tel Mora", "Vos", "Vivec"
	set status to 5
endif

if ( status == 5 )

 	set button2 to GetButtonPressed

 	if ( button2 >= 1 )
 	playsound "conjuration hit"
 	set status to 0
 	endif

 	if ( button2 == 0 ) ;Nulle Part
 	set status to 0
 	return
 	elseif ( button2 == 1 ) ;Sadrith Mora
 	Player->PositionCell 150299, 31719, 652 135 "Sadrith Mora"
 	elseif ( button2 == 2 ) ;Seyda Nihyn
 	Player->PositionCell -11136, -70831, 230 190 "seyda nihyn"
 	elseif ( button2 == 3 ) ;Suran
 	Player->PositionCell 54924, -52728, 882 325 "suran"
 	elseif ( button2 == 4 ) ;Tel Aruhn
 	Player->PositionCell 125328, 45809, 1470 0 "tel aruhn"
 	elseif ( button2 == 5 ) ;Tel Branora
 	Player->PositionCell 124974, -102299, 777 90 "tel branora"
 	elseif ( button2 == 6 ) ;Tel Mora
 	Player->PositionCell 107025, 117293, 185 30 "tel mora"
 	elseif ( button2 == 7 ) ;Vos
 	Player->PositionCell 92991, 116762, 1396 90 "vos"
 	elseif ( button2 == 8 ) ;Vivec
 	Player->PositionCell 46967, -81879, 772 270 "vivec"
 	endif

endif

End Teleport 

en fait, je m'étais entêté, car le script que j'ai poster en 1er lieu fonctionnais impeccable sur un objet équipable, donc je en comprenais pas pourquoi il ne fonctionnais pas, quand je changeais la variable d'équipement en variable d'activation :s

Merci en tout cas

Modifié par Ariolas, 02 juillet 2010 - 12:59.