Aucune réponse à ce sujet

[Gamall]

Créer un effet de choc télékinétique façon "Force Push" : Screen

En fait, il n'y a pas de moyen simple (à ma connaissance) d'envoyer une impulsion Havok sur un acteur. En revanche, on peut assez facilement simuler la chose :

Il suffit d'utiliser une animation spectaculaire, et en plein milieu, de rendre l'acteur inconscient (par la fatigue ou la paralysie). C'est alors le moteur physique qui prend le relai.


Voici le code que j'utilise pour obtenir le choc psionique de mon mod Gamagie : c'est le principe standard pour lancer des sorts aoe sur soi : un faux sort et un activateur qui lance le vrai. Et pas de PlaceAtMe, bien entendu, PlaceAtMe, c'est le mal  

Voici le faux sort, dont le but principal est d'appeler un activateur qui lance le vrai

scn GAMAChocPsionPhonySpellScript

ref ca

Begin ScriptEffectStart

	set ca to GAMASpellCaster1

	ca.disable
	ca.moveto player, 0, 0, 150
;	ca.enable
	playsound ambthunder
	ca.cast GAMAChocPsionIV0 ca

End

GAMASpellCaster1 est mon activateur lance-sort-fait-tout-cuisinier-esclave


Et voici le sort de télékinésie à proprement parler.

scn GAMAChocPsioniqueSpellScript

ref me
float timer

Begin ScriptEffectStart

	set me to getself

	if me == player 
		return
	endif

	if me.getav willpower > player.getav willpower
		message "Une cible a résisté"
		return
	endif

	look player
	playgroup dodgeback, 1

	set timer to .4

;playgroup stagger, 0
;playgroup stagger, 2
;playgroup backward, 1

End

Begin ScriptEffectUpdate

	if me == player
		return
	endif

	if timer > 0
		set timer to timer - GetSecondsPassed
		return
	endif
	addspell GAMAMaledictionPsionique

End

Begin ScriptEffectFinish

	if me == player
		return
	endif

	playgroup idle, 1
	removespell GAMAMaledictionPsionique
	stoplook

End

GAMAMaledictionPsionique est tout bêtement un effet constant de drain de fatigue 1000.

À part cela je pense que le code est assez explicite.