13 réponses à ce sujet

[Ptolémis]

j'ai commencé un mod Familier. comme le nom le dit, le PJ est accompagné d'une créature qui le suit (AiEscort, jusque là c'est assez simple) mais je bloque dejà sur le levelup, comment faire en sorte qu'il monte un niveau en combatant ? vu que les créatures n'ont pas de compétences secondaires, j'aurai aimé faire comme dans Wow avec une barre d'XP mais celle-ci se remplierai lorsque le familier combaterai voire même (s'il est fort) tuerai l'ennemi... j'ignore s'il existe un fonction qui reconnaitrai ce genre de situation ou si tout simplement il n'en existe pas  
merci à quiconque souhaiterai m'aider pour ce problème

[a3jv]

A ma connaissance, il n'existe rien de tel pour les NPC/créatures, mais ma connaissance est limitée.
La soluce employée généralement est de faire évoluer le familier avec le PJ (ou seul suivant le temps passé ou des actions) via des scripts et dialogues.
Maintenant, quelqu'un a peut-être trouvé mieux.

[John Athan]

Bonsoir,

désolé je se sais pas te répondre.

J'ai néanmoins quelque chose à dire- mais-je me trompe peut-être- il me semble qu'il existe déjà un mos pour les familiers...
Quelqu'un de plus compétent pour infirmer ou confirmer ?

[Ptolémis]

J'ai dwl cette nuit le mod Familiers de Lord Mortim avec le diablotin Iro. C'est à peu près ce que je recherche  
j'ai une autre question concernant tjrs le levelup, lorsque l'on applique un niveau supplémentaire à la créature ( Setlevel CurrentLevel, avec Set CurrentLevel to (player->GetLevel) evidemment accompagné d'une reconnaissance à chaque évolution du PJ, If ( CurrentLevel < (player->GetLevel) ) ... ou du moins tous s'y rapprochant    ), est-ce que les cara de la créature montent aussi ? ou faut-il les faire monter par un script ?

[a3jv]

Non, rien ne progresse seul, il faut aussi les faire monter par script (ou result dialogue) en choisissant ce qui convient le mieux par rapport à la créature ou en alignant aussi avec les caractéristiques du PJ. Pareil pour les talents.
Bon courage !...
Je viens peut-être de dire une connerie ! En fait, si la case 'auto calculate state' (un truc dans ce genre) est cochée, peut être que les caracts progressent avec la progression de niveau !?
Donc je ne sais pas !
Donc je ferai peut-être mieux de supprimer ce message !
Mais bon, je le laisse, ça te feras de la lecture.

Modifié par a3jv, 21 août 2005 - 14:31.

[Ptolémis]

negatif, cette case n'existe pas pour les créatures...
pour finir je crois que je vais bidouiller avec une randomize un fois que ya un levelup, ainsi yora des valeurs supplémentaires aléatoires pour les cara. mais il reste un pb : si le PJ est au lvl33 (ce n'est qu'un exemple) et que la créature apparait directement au lvl33, ses cara restent inchangées. dans cette situation, la randomize ne sert à rien vu qu'il y à 33 niveaux à rattraper. j'ai pensé à qqchose, mais j'ignore s'il y à un équivalent du Do-Loop-While dans le language du Tescs, si oui, je saurai peut etre travailler sur la différence du lvl du PJ avec celui de la créature et ainsi obtenir une initialisation des cara plus correcte.

Modifié par Ptolémis, 21 août 2005 - 15:40.

[Nwart]

Tu pourrais peut-être faire en sorte que le familier ne monte que d'un niveau à la fois... Bon, bien sûr, c'est un peu chiant pour le PJ de devoir demander 33 fois à son familier de monter de niveau...

Sinon, il n'y a pas de while, juste des scripts qui s'exécutent à chaque frame.
une idée comme ça:
quand on demande un level-up, mettre une variable montéeDeNiveau du familier à 1

et dans le script du familier

si montéeDeNiveau = 1,
  si niveau inférieur à celui du PJ, monter d'un niveau (avec montée de caracs)
  sinon mettre montéeDeNiveau à 0

EDIT:
Pardon, je dis une connerie, y'a un while,

While ( condition ) 
; instructions à exécuter 
EndWhile

La différence, c'est que l'utiliser peut "geler" l'écran tant que la montée de niveau n'est pas finie. Mais dans ce cas, comme ça n'arrive que rarement et que ça ne devrait pas être trop long, ça devrait suffire.

Modifié par Nwart, 21 août 2005 - 17:14.

[Ptolémis]

oui en effet, je m'orientai vers cette solution, mais tout de même vu que c'est chiant pr le PJ, j'ai essayé de bidouillé et ça donne qqchose comme ça, mais ça marche tjrs pas. (le script ci-dessous est associé au familier en question)

Spoiler

begin FAM_creature

short Rnd
short FAM_LevelOnce
short fam_health
short fam_strength
short fam_speed
short fam_endurance
short fam_intelligence
short fam_agility
short MsgState
short button

if ( MenuMode == 1 )
	return
endif

if ( OnActivate == 1 )
	set MsgState to 1
endif

if ( MsgState == 0 )
	return
endif

if ( MsgState == 1 )
	Messagebox, "Que voulez faire ?" "Donner les ordres." "Consulter les caractéristiques." "Rien."
	set MsgState to 2
endif

if ( MsgState == 2 )
	
	set button to GetButtonPressed

	if ( button == 0 )
  MessageBox "Votre familier attend les ordres." "Suis-mois." "Reste là." 
  set MsgState to 3
	endif
	if ( button == 1 )
  if ( GetLevel < ( player->GetLevel ) ); ça cafouille à partir d'ici...
 	 set FAM_LevelOnce to ( ( player->GetLevel ) - GetLevel )
 	 MessageBox "Votre familier vient de monter %g niveau(x).", FAM_LevelOnce 
  endif
  if ( FAM_LevelOnce > 0 )
 	 Set FAM_CurrentLevel to ( GetLevel + 1 )
 	 SetLevel FAM_CurrentLevel; ...jusqu'à ici
 	 Set Rnd to Random 6

 	 if ( Rnd == 0 )
    modhealth 3
    modstrength 1
    modspeed 1
    modintelligence 1
    modagility 1
    modendurance 1
 	 elseif ( Rnd == 1 )
    modhealth 2
    modstrength 2
    modspeed 1
    modintelligence 1
    modagility 2
    modendurance 1
 	 elseif ( Rnd == 2 )
    modhealth 1
    modstrength 2
    modspeed 2
    modintelligence 1
    modagility 1
    modendurance 2
 	 elseif ( Rnd == 3 )
    modhealth 2
    modstrength 1
    modspeed 3
    modintelligence 2
    modagility 1
    modendurance 1
 	 elseif ( Rnd == 4 )
    modhealth 3
    modstrength 3
    modspeed 2
    modintelligence 2
    modagility 1
    modendurance 2
 	 elseif ( Rnd == 5 )
    modhealth 2
    modstrength 4
    modspeed 2
    modintelligence 1
    modagility 3
    modendurance 2
 	 endif
  endif

  set fam_health to GetHealth
  set fam_strength to GetStrength
  set fam_speed to GetSpeed
  set fam_endurance to GetEndurance
  set fam_intelligence to GetIntelligence
  set fam_agility to GetAgility
  MessageBox "                  Niveau : %g                           Santé : %g                Force : %g            Intelligence : %g        Endurance : %g  Rapidité : %g              Agilité : %g", FAM_CurrentLevel, fam_health, fam_strength, fam_intelligence, fam_endurance, fam_speed, fam_agility
  set MsgState to 0
	endif
	if ( button == 2 )
  set MsgState to 0
	endif
endif

if ( MsgState == 3 ) 
	
	set button to GetButtonPressed

	if ( button == 0 )
  AiFollow, Player 0 0 0 0 0
	endif
	if ( button == 1 )
  AiWander 0 0 0 40 30 20 0 0 0 0 0 0
	endif
	set MsgState to 0
endif

end

si qq'un peut m'expliquer ce qui ne va pas...

Modifié par Ptolémis, 21 août 2005 - 17:22.

[Ptolémis]

@Nwart : OK, je vai regarder ça, merci

[a3jv]

Il manque un 'to' (ou un '.') et j'enlèverai les doubles parenthèses.

Citation

if ( GetLevel < player->GetLevel )
      set FAM_LevelOnce to ( player->GetLevel - GetLevel )
      MessageBox "Votre familier vient de monter %g niveau(x).", FAM_LevelOnce
      endif
      if ( FAM_LevelOnce > 0 )
      Set FAM_CurrentLevel to ( GetLevel + 1 )
      SetLevel to FAM_CurrentLevel

Pour les 'Random', c'est peut-être superflu vu que les résultats restent invisibles du joueur, autant ne mettre qu'une possibilité ou les réduire à 3 pour alléger un peu. Enfin c'est toi qui voit.
Sinon, j'ai pris un mal de tête à vérifier si pas trop de 'if' 'elseif' dans la boucle if/endif mais ça a l'air bon.

Modifié par a3jv, 21 août 2005 - 18:55.

[Ptolémis]

ok, je regarde ça tout de suite et j'éditerai, merci a3jv

EDIT: la correction avec les parenthèses et le 'to' ne changent rien. j'ai cherché à alleger le script en supprimant le :

if ( GetLevel < ( player->GetLevel ) )
 set FAM_LevelOnce to ( ( player->GetLevel ) - GetLevel )
 MessageBox "Votre familier vient de monter %g niveau(x).", FAM_LevelOnce
endif

et en le remplaçant par un :

if ( GetLevel < player->GetLevel )
	set PCLevel to ( player->GetLevel )
	MessageBox "Votre familier vient d'atteindre le niveau %g." PCLevel; en variable locale
endif

et ça donne ce morceau, lorsque button == 1, càd lorsque l'on désire consulter les caracs :

if ( GetLevel < player->GetLevel )
	set PCLevel to ( player->GetLevel )
	MessageBox "Votre familier vient d'atteindre le niveau %g." PCLevel 
endif
While ( GetLevel < player->GetLevel )
	Set FAM_CurrentLevel to ( GetLevel + 1 )
	SetLevel to FAM_CurrentLevel
	Set Rnd to Random 6

	if ( Rnd == 0 )
  modhealth 3
  .......
	endif
endWhile

set fam_health to GetHealth
set fam_strength to GetStrength
set fam_speed to GetSpeed
set fam_endurance to GetEndurance
set fam_intelligence to GetIntelligence
set fam_agility to GetAgility
MessageBox "......"
set MsgState to 0

dans le jeu, lorsque button == 1, le script saute tout de suite au messagebox, "...." qui affiche les caracs mais pas moyen de démarrer la boucle du levelup... je soupçonne donc la condition if ( GetLevel < player->GetLevel ) de ne pas être correcte

Modifié par Ptolémis, 22 août 2005 - 12:12.

[Ptolémis]

bon bon bon... après mon aprè-midi flaché sur le script, j'ai fait quelques modifications :
- j'ai viré la globale FAM_CurrentLevel qui ne sert à rien en dehors du script alors je l'ai passée en locale, FAM_level (tout simplement)
- j'ai viré le While/endWhile (hé ouais, j'ai planté l'ordi avc   ) et j'ai procédé avec une imbrication de if/else/endif et un renvoi en debut de script pour l'évolution des caracs.

Spoiler

if ( FAM_caracs == 1 )
   Set FAM_level to ( GetLevel + 1 )
   SetLevel FAM_level
   Set Rnd to Random 3; oui ok, j'ai mis 3
   if ( Rnd == 0 )
      .....
   endif
   if ( FAM_level == PCLevel )
      set FAM_caracs to 0
   else
      set FAM_caracs to 1
   endif
endif
...
if ( button == 1 )
   set PCLevel to ( player->GetLevel )
   set FAM_level to GetLevel
   if ( FAM_level < PCLevel )
     MessageBox "Votre familier vient d'atteindre le niveau %g." PCLevel 
     set FAM_caracs to 1
     set MsgState to 0
   endif
	
   if ( FAM_level == PCLevel )
     ....
     MessageBox "...."
     set MsgState to 0
   endif
endif

j'ai constaté de beaux progrès mais à présent, j'ai observé un autre petit et tout dernier problème (enfin j'éspère), c'est le :

Set FAM_level to ( GetLevel + 1 )
SetLevel (to) FAM_level; avec ou sans le 'to', il se passe rien

d'ailleur j'ai lu ça dans les contents : "Level (only works with Set and Get)" alors bon, je continu de ramer  

Modifié par Ptolémis, 22 août 2005 - 16:55.

[Angora]

C'est un gros problème, les fonctions setTruc semblent rarement fonctionner avec des variables... Est-ce que SetLevel accepte de fonctionner avec une constante, du style SetLevel 20 ? En ce cas, il serait possible d'avoir recours à une sorte de "case"

if ((player->getLevel) > 30)
   setLevel 30
elseif ((player->getLevel) > 20)
   setLevel 20
elseif ((player->getLevel) > 10)
   setLevel 10
endif

Mais ce serait assez pénible à faire si on veut plus détaillé que ça. (Là, je me contente des niveaux 11 à 31+, avec le familier qui gagne un gros boost tout les dix niveaux et rien entre-temps.)

D'un autre côté, je suis pas convaincu que le niveau serve à grand'chose vu que les caracs sont réglées à part. Enfin, j'ai pas beaucoup scripté de bestioles, peut-être n'ont-elles pas de fonction SetCombat, SetMagic et SetStealth pour leur compétences à elles.

[Ptolémis]

oui je vien de regardé et c plutot long à taper... et pis aussi t'as raison, le niveau peu rester comme il est puisqu'il est invisible au player. alors j'ai viré la ligne :

Set FAM_level to ( GetLevel + 1 )
SetLevel FAM_level

afin de la remplecer par :

Set FAM_level to FAM_level + 1

qui est à présent plus utile. alors vu que j'ai commencé, j'ai été plus loin et mtn ça marche impec'  
pour les interressés : (j'ai fini par virer la randomize)

Spoiler

begin FAM_creature

short fam_health
short fam_strength
short fam_speed
short fam_endurance
short fam_intelligence
short fam_agility
short MsgState
short button
short PCLevel
short FAM_level
short FAM_levelup

if ( MenuMode == 1 )
	return
endif

if ( OnDeath == 1 ); le familier est mort, le player n'en possède donc plus.
	MessageBox, "Votre familier est mort."
	set Familier to 0
endif

if ( OnActivate == 1 )
	if ( OnDeath == 1 )
  Activate
	endif
	if ( Familier == 1 ); bien entendu pour que le script fonctionne, Familier == 1, càd que le player soit en possession du familier
  set MsgState to 1
	else 
  return
	endif
endif

if ( MsgState == 0 )
	return
endif

if ( FAM_levelup == 1 ); mise au même niveau du familier avec le player
	set FAM_level to FAM_level + 1
	modhealth 2
	modstrength 1
	modspeed 1
	modintelligence 1
	modagility 1
	modendurance 1
	
	if ( FAM_level == PCLevel )
  set FAM_levelup to 0
	else
  set FAM_levelup to 1
	endif
endif

if ( MsgState == 1 )
	Messagebox, "Que voulez faire ?" "Donner les ordres." "Consulter les caractéristiques." "Rien."
	set MsgState to 2
endif

if ( MsgState == 2 )
	
	set button to GetButtonPressed

	if ( button == 0 )
  MessageBox "Votre familier attend les ordres." "Suis-mois." "Reste là." "Tu es libre."
  set MsgState to 3
	endif
	if ( button == 1 )
  set PCLevel to ( player->GetLevel )
  if ( FAM_level < PCLevel )
 	 MessageBox "Votre familier vient d'atteindre le niveau %g." PCLevel 
 	 set FAM_levelup to 1
  endif
  
  if ( FAM_level == PCLevel )
 	 set fam_health to GetHealth
 	 set fam_strength to GetStrength
 	 set fam_speed to GetSpeed
 	 set fam_endurance to GetEndurance
 	 set fam_intelligence to GetIntelligence
 	 set fam_agility to GetAgility
 	 MessageBox "                  Niveau : %g                        Santé : %g               Force : %g Intelligence : %g        Endurance : %g  Rapidité : %g              Agilité : %g", PCLevel, fam_health, fam_strength, fam_intelligence, fam_endurance, fam_speed, fam_agility
  endif
	endif
	if ( button == 2 )
  set MsgState to 0
	endif
endif

if ( MsgState == 3 ) 
	
	set button to GetButtonPressed

	if ( button == 0 )
  AiFollow, Player 0 0 0 0 0
  set MsgState to 0
	endif
	if ( button == 1 )
  AiWander 0 0 0 40 30 20 0 0 0 0 0 0
  set MsgState to 0
	endif
	if ( button == 2 )
  AiWander 1000 0 0 40 30 20 0 0 0 0 0 0
  set Familier to 0
  MessageBox, "Vous venez de relâcher votre familier."
	endif
endif

end

donc c'est bon, topic résolu

Modifié par Ptolémis, 23 août 2005 - 13:56.