Aucune réponse à ce sujet

[HawkFest]

Je reproduis ici en FR la description d'un bug que j'ai décrit sur le forum de Bethesda, et maintenant lié à la doc de GetItemCount (lien de la section "Notes" en bas de page).

Problème : quand un mot-clé est donné en argument,GetItemCOunt fonctionne sur un conteneur mais pas sur un acteur.

Contexte original : déterminer le nombre de potions dans l'inventaire du joueur, pour par la suite les bouger vers un conteneur HUB partagé dans une cellule inaccessible. Pour se faire on utilise une "liste blanche" des items à traiter. En l'occurrence, un Formlist de Keywords définissant une catégorie : tous les items ayant l'un des mots-clés de la liste seront traités.

Dans le script suivant, le test fut fait avec une Formlist contenant un seul keyword : VendorItemPotion. Je n'ai pas mis tout le script, seulement l'essentiel afin qu'il soit fonctionnel pour que vous puissiez tester:

Spoiler

Scriptname fj_BHStorageSingleCategoryScript extends ObjectReference

ObjectReference Property rContainerCategoryHUB Auto
{Conteneur HUB associe partage dans une cellule inaccessible}
Formlist Property fCategory Auto
{Formlist de Keywords : tout item ayant l'un des mots-cles de la liste seront traites}

Int iIndexKeywords ;Index pour "traverser" le Formlist
Int iCountPerK ;Nombre d'items ayant un mot-clé spécifique de la Formlist
Int iCountItem ;Nombre total d'items permis par la Formlist

Event OnInit()
  iCountKeywords = fCategory.GetSize()
EndEvent

Event OnActivate(ObjectReference akActionRef)
If akActionRef == Game.GetPlayer()
  iCountItem = 0
  iIndexKeywords = iCountKeywords ; number of Keywords in the Formlist
  ShowMenu(0, akActionRef)
Endif
EndEvent

Function ShowMenu(Int iButton = 0, ObjectReference akActionRef)
iButton = mMainMenuFourChoices.Show()
Game.DisablePlayerControls(0, 0, 0, 0, 0, 1)
If iButton == 0 ;*** TOUT RANGER
  While iIndexKeywords
	iIndexKeywords -= 1
	iCountPerK = akActionRef.GetItemCount(fCategory.GetAt(iIndexKeywords) As Keyword)
	iCountItem += iCountPerK
	akActionRef.RemoveItem(fCategory.GetAt(iIndexKeywords) As Keyword, iCountPerK, True, rContainerCategoryHUB)
debug.Notification("TOUT RANGER  iCountKeywords = "+iCountKeywords+"; iIndexKeywords = "+iIndexKeywords+"; iCountPerK = "+iCountPerK+"; iCountItem = "+iCountItem)
  EndWhile

ElseIf iButton == 1 ;*** TOUT PRENDRE
  rContainerCategoryHUB.RemoveAllItems(akActionRef, True, True)

ElseIf iButton == 2 ;*** INVENTAIRE
  rContainerCategoryHUB.Activate(akActionRef)
  Utility.Wait(0.1)
  While iIndexKeywords
	iIndexKeywords -= 1
	iCountPerK = rContainerCategoryHUB.GetItemCount(fCategory.GetAt(iIndexKeywords) As Keyword)
	iCountItem += iCountPerK
debug.Notification("INVENTAIRE  iCountKeywords = "+iCountKeywords+"; iIndexKeywords = "+iIndexKeywords+"; iCountPerK = "+iCountPerK+"; iCountItem = "+iCountItem)
  EndWhile

ElseIf iButton = 3 ;*** ANNULER
EndIf
Game.EnablePlayerControls(0, 0, 0, 0, 0, 1)
EndFunction

Dans la section TOUT RANGER (iButton = 0) :

iCountPerK = akActionRef.GetItemCount(fCategory.GetAt(iIndexKeywords) As Keyword)

montre des valeurs incorrectes pour la variable iCountPerK (nombre d'items comportant un mot-clé spécifique) : on obtient des valeurs négatives, même quand aucun item n'est détecté.

Cependant, dans la section INVENTAIRE (iButton = 2) :

iCountPerK = rContainerCategoryHUB.GetItemCount(fCategory.GetAt(iIndexKeywords) As Keyword)

fonctionne tel que prévu, iCountPerK retournant des valeurs correctes.

Une solution est de vider le contenu du PJ dans un coffre tampon, puis d'utiliser ce dernier à la place du PJ (sans oublier de tout reprendre après traitement).

---

Bien que ce ne soit pas lié au sujet, il faut mentionner que le script n'aura pas le comportement attendu dans sa section TOUT RANGER (même si on peut faire le décompte par Keyword  avec la solution ci-haut mentionnée) :

akActionRef.RemoveItem(fCategory.GetAt(iIndexKeywords) As Keyword, iCountPerK, True, rContainerCategoryHUB)

ne fonctionne pas même si en jeux ça ne crash pas et que le compilateur ne dise rien : RemoveItem n'accepte que des Form, et ne comprend donc pas le premier argument qui est un Keyword.

Pour palier à cela, une solution rapide (mais peu élégante car on verrait les messages associés aux quêtes, telle celle consistant à trouver 10 peux d'ours ou les quêtes de ceuillette), serait de remplacer la ligne en question par une instruction qui bouge tout le contenu du joueur vers le conteneur HUB partagé dans la cellule inaccessible, puis de laisser ce dernier filtrer les éléments ajoutés en renvoyant au joueur ceux qui ne passent pas sa "liste blanche" (le Formlist de Keywords)  :

1. Remplacer la ligne en cause par :

akActionRef.RemoveAllItems(rContainerCategoryHUB, True, False)
Utility.Wait(0.05)

2. Attacher le script suivant au conteneur HUB partagé :

Spoiler

Scriptname fj_BHStorageHUBScript extends ObjectReference

FormList Property fCategory Auto
{Formlist des elements de la categorie en cours de classement.}
Bool Property bIsCategoryOfKeywords Auto
{Mentionne si on utilise une Formlist de keywords}

Int iIndexKeywords
bool IsAllowed = False

Event OnItemAdded(Form akBaseItem, int aiItemCount, ObjectReference akItemReference, ObjectReference akSourceContainer)
If bIsCategoryOfKeywords
	IsAllowed = False
	iIndexKeywords = fCategory.GetSize()
	While iIndexKeywords
		iIndexKeywords -= 1
		If akBaseItem.HasKeyword(fCategory.GetAt(iIndexKeywords) As Keyword)
			IsAllowed = True
			iIndexKeywords = 0
		EndIf
	EndWhile
	If !IsAllowed
		self.RemoveItem(akBaseItem, aiItemCount, True, akSourceContainer)
	EndIf
ElseIf !fCategory.HasForm(akBaseItem)
   self.RemoveItem(akBaseItem, aiItemCount, True, akSourceContainer)
EndIf
EndEvent

Note -  Le script du point 2 accepte deux types de "liste blanche" : Formlist de Keywords, ou Formlist de Form (d'items). Si on fournit une Formlist de Keywords, il faut initialiser la propriété bIsCategoryOfKeywords à True via le CK.

Modifié par HawkFest, 14 février 2013 - 22:05.