begin endgameMessage
short doOnce
Short QuestionState
Short button
Short Gotkey
If ( MenuMode == 1 )
Return
EndIf
if ( getdistance player < 1000 )
if( doOnce == 0 )
FadeTo 100 1
FadeTo 0 3.0
MessageBox "Merci d'avoir joué à The Sword Of the Perithia d'Andre Sergoyan. Version française : WiWiland SOP Team : Gilles_K, Wiwi, Virgo, DarkNeoWars, Billylebegue, Ethaniel."
set doOnce to 1
endif
endif
if( doOnce == 0 )
return
endif
if( QuestionState == 0 )
messageBox "Vous pouvez continuer la quête dans Morrowind, mais ATTENTION si vous essayez de retourner dans Rasman, comme vous êtes un banni, vous serez tué immédiatement. Voulez-vous continuer la quête de morrowind ?" "Oui" "Non"
set QuestionState to 1
endif
if( QuestionState == 1 )
set button to GetButtonPressed
if( button == 0)
set QuestionState to 2
; ici mettre la position, enlever les objets, mettre un message
set sopvar to 2
set HeartDestroyed to 0
player->removeitem "wet suit" 1
player->removeitem "thief_ring" 1
player->removeitem "troll's Tooth" 1
player->removeitem "Angelic bow of sure flight" 1
; remettre les régions de morrowind
ModRegion, "Ascadian Isles Region", 45, 45, 0, 0, 5, 5, 0, 0
ModRegion, "Azura's Coast Region", 25, 45, 10, 10, 5, 5, 0, 0
ModRegion, "Bitter Coast Region", 10, 60, 10, 0, 10, 10, 0, 0
ModRegion, "Grazelands Region", 30, 40, 5, 5, 10, 10, 0, 0
;disable all the boat stuff outside and the guys
"CharGen Boat"->Disable
"CharGen Boat Guard 1"->disable
"CharGen Boat Guard 2"->disable
"CharGen Dock Guard"->disable
"CharGen_cabindoor"->disable
"CharGen_chest_02_empty"->disable
"CharGen_crate_01"->disable
"CharGen_crate_01_empty"->disable
"CharGen_crate_01_misc01"->disable
"CharGen_crate_02"->disable
"CharGen_lantern_03_sway"->disable
"CharGen_ship_trapdoor"->disable
"CharGen_barrel_01"->disable
"CharGen_barrel_02"->disable
"CharGenbarrel_01_drinks"->disable
"CharGen_plank"->disable
"Captain ron"->Disable
set gotKey to ( Player->GetItemCount, "ring_keley" )
if (gotkey == 0)
player->Additem "ring_keley" 1
endif
enableplayermagic
enableplayerfighting
Set Gotkey to ( player->Getlevel )
set Gotkey to ( gotkey*8+50 )
player->Sethealth gotkey
"player"->Position -10870, -72017, 263, 0
journal "ew_letter" 192
; à partir de là il faut lancer le script qui va tester si le joueur revient dans Rashman avec l'index ew_letter = 192.
StartScript NoSOP
Stopscript endgameMessage
elseif( button == 1)
set QuestionState to 2
; ici mettre message de fin
MessageBox "Et à bientôt pour d'autres aventures" "OK"
Stopscript endgameMessage
endif
endif
end endgameMessage